添加计算字段

将计算字段添加到分析

1. 打开QuickSight 控制台。

2. 打开要更改的分析。

3. 在 “数据” 窗格中，选择左上角的添加，然后选择 + 计算字段。

   1. 在打开的计算编辑器中，执行以下操作：

   2. 为计算字段输入名称。

   3. 使用数据集、函数和运算符中的字段输入公式。

4. 完成后，选择保存。

为数据集添加或编辑计算字段

1. 打开您希望使用的数据集。有关更多信息，请参阅 编辑数据集。

2. 在“数据准备”页面上，执行以下操作：

   • 要创建新字段，请选择左侧的添加计算字段。

   • 要编辑现有的计算字段，请从左侧的计算字段中选择该字段，然后从上下文（右键单击）菜单中选择编辑。

   

3. 在计算编辑器中，为添加标题输入描述性名称来命名新的计算字段。此名称出现在数据集的字段列表中，因此应与其他字段相似。在本示例中，我们将字段命名为 Total Sales This Year。

4. （可选）添加注释，例如用斜杠和星号将文本括起来，以说明表达式的作用。

   /* Calculates sales per year for this year*/

5. 确定要使用的指标、函数和其他项目。在本示例中，我们需要确定以下内容：

   • 要使用的指标

   • 函数：ifelse 和 datediff

   我们想构建一个语句，类似于“如果销售发生在今年，则显示总销售额，否则显示 0。”

   要添加 ifelse 函数，请打开函数列表。选择全部以关闭所有函数的列表。现在，您应该会看到函数组：聚合、条件、日期等。

   选择条件，然后双击 ifelse 将其添加到工作区。

   ifelse()

6. 将光标放在工作区的括号内，然后添加三个空白行。

   ifelse(
                                               
                                               
                                               
   )

7. 将光标放在第一个空白行上，找到 dateDiff 函数。它列在日期下的函数中。您也可以通过输入 date 使用搜索功能查找。dateDiff 函数返回名称中包含 date 的所有函数。它不会返回日期下列出的所有函数；例如，搜索结果中缺少 now 函数。

   双击 dateDiff 将其添加到 ifelse 语句的第一个空白行。

   ifelse(
   dateDiff()                                            
                                               
                                               
   )

   添加 dateDiff 使用的参数。将光标放在 dateDiff 括号内以开始添加 date1、date2 和 period：

   1. 对于 date1：第一个参数是包含日期的字段。在字段下找到它，然后双击它或输入其名称将其添加到工作区。

   2. 对于 date2，添加逗号，然后选择 truncDate() 作为函数。在括号内添加周期和日期，如下所示：truncDate( "YYYY", now() )

   3. 对于 period：在 date2 后面添加逗号并输入 YYYY。这是一年的周期。要查看所有支持的周期列表，在函数列表中找到 dateDiff，然后选择了解更多以打开文档。如果您已经像现在一样查看文档，请参阅 dateDiff。

   如果您愿意，可以添加一些空格以提高可读性。表达式应如下所示。

   ifelse(
      dateDiff( {Date}, truncDate( "YYYY", now() ) ,"YYYY" )                                       
                                               
                                               
   )

8. 指定返回值。在我们的示例中，ifelse 中的第一个参数需要返回 TRUE 或 FALSE 的值。因为我们想要当前年份，并且将其与今年进行比较，所以指定 dateDiff 语句应返回 0。对于销售年份和当前年份之间没有区别的行，ifelse 的 if 部分评估为 true。

      dateDiff( {Date}, truncDate( "YYYY", now() ) ,"YYYY" ) = 0 

   要为去年 TotalSales 创建字段，可以将 0 更改为 1。

   使用 addDateTime 而不是 truncDate，也能达到同样的目的。然后，对于之前的每一年，更改 addDateTime 的第一个参数来代表每一年。为此，您可以使用 -1 表示去年，-2 表示之前的一年，依此类推。如果您使用 addDateTime，则将每年的 dateDiff 函数保留为 = 0。

      dateDiff( {Discharge Date}, addDateTime(-1, "YYYY", now() ) ,"YYYY" ) = 0 /* Last year */

9. 将光标移到 dateDiff 下方的第一个空白行。添加逗号。

   对于 ifelse 语句的 then 部分，我们需要选择包含销售额的度量（指标）TotalSales。

   要选择字段，打开字段列表，然后双击字段将其添加到屏幕上。或者可以输入名称。在包含空格的名称周围添加大括号 { }。您的指标可能有不同的名称。您可以通过字段前面的数字符号（#）判断哪个字段是指标。

   现在，表达式应如下所示。

   ifelse(
      dateDiff( {Date}, truncDate( "YYYY", now() ) ,"YYYY" ) = 0
      ,{TotalSales}                            
                                              
   )

10. 添加 else 子句。ifelse 函数不需要子句，但我们想添加。出于报告的目的，您通常不希望有任何 null 值，因为有时会省略带 null 值的行。

    我们将 ifelse 的其余部分设置为 0。结果是，对于包含往年销售额的行，该字段为 0。

    为此，请在空白行上添加一个逗号，然后添加 0。如果您在开头添加了注释，则最终 ifelse 表达式应如下所示。

    /* Calculates sales per year for this year*/
    ifelse(
       dateDiff( {Date}, truncDate( "YYYY", now() ) ,"YYYY" ) = 0
       ,{TotalSales}                            
       ,0                                         
    )

11. 选择右上角的保存以保存您所做的工作。

    如果表达式中有错误，编辑器会在底部显示错误消息。检查表达式中是否有红色的波浪线，然后将光标悬停在该行上以查看错误消息内容。常见错误包括标点符号缺失、参数缺失、拼写错误和数据类型无效。

    要避免进行任何更改，请选择取消。

将参数值添加到计算字段

1. 您可以在计算字段中引用参数。通过将参数添加到表达式中，可以添加该参数的当前值。

2. 要添加参数，打开参数列表，然后选择要包含其值的参数。

3. （可选）要手动向将参数添加到表达式，请键入参数的名称。然后用大括号 {} 将其括起来，并加上 $ 前缀，例如 ${parameterName}。

更改计算字段的数据类型

• 对于计算字段（左侧），选择要更改的字段，然后从上下文（右键单击）菜单中选择更改数据类型。

删除计算字段

• 对于计算字段（左侧），选择要更改的字段，然后从上下文（右键单击）菜单中选择删除。