支持的 PL/pgSQL 语句

IF ... THEN

IF boolean-expression THEN
  statements
END IF;

下面是一个示例。

IF v_user_id <> 0 THEN
  UPDATE users SET email = v_email WHERE user_id = v_user_id;
END IF;               

IF ... THEN ... ELSE

IF boolean-expression THEN
  statements
ELSE
  statements
END IF;

下面是一个示例。

IF parentid IS NULL OR parentid = ''
THEN
  return_name = fullname;
  RETURN;
ELSE
  return_name = hp_true_filename(parentid) || '/' || fullname;
  RETURN;
END IF;           

IF ... THEN ... ELSIF ... THEN ... ELSE

关键词 ELSIF 也可以拼写成 ELSEIF。

IF boolean-expression THEN
  statements
[ ELSIF boolean-expression THEN
  statements
[ ELSIF boolean-expression THEN
  statements
    ...] ]
[ ELSE
  statements ]
END IF;

下面是一个示例。

IF number = 0 THEN
  result := 'zero';
ELSIF number > 0 THEN
  result := 'positive';
ELSIF number < 0 THEN
  result := 'negative';
ELSE
  -- the only other possibility is that number is null
  result := 'NULL';
END IF;                  

简单 CASE

CASE search-expression
WHEN expression [, expression [ ... ]] THEN
  statements
[ WHEN expression [, expression [ ... ]] THEN
  statements
  ... ]
[ ELSE
  statements ]
END CASE;

简单 CASE 语句根据操作数是否相等提供有条件的执行。

search-expression 值求值一次，接下来与 WHEN 子句中的各个 expression 进行比较。如果找到匹配，则对应的 statements 运行，然后控制传递到 END CASE 之后的下一个语句。不对后面的 WHEN 表达式求值。如果未找到匹配，则运行 ELSE statements。但是，如果没有 ELSE，则将引发 CASE_NOT_FOUND 异常。

下面是一个示例。

CASE x
WHEN 1, 2 THEN
  msg := 'one or two';
ELSE
  msg := 'other value than one or two';
END CASE;                  

搜索 CASE

CASE
WHEN boolean-expression THEN
  statements
[ WHEN boolean-expression THEN
  statements
  ... ]
[ ELSE
  statements ]
END CASE;

CASE 的搜索形式提供有条件执行，基于布尔值表达式求值为对还是错。

每个 WHEN 子句的 boolean-expression 按顺序求值，直至发现得到 true 的子句。然后，对应的语句运行，然后控制传递到 END CASE 之后的下一个语句。不对后面的 WHEN 表达式求值。如果没有找到 true 结果，则运行 ELSE statements。但是，如果没有 ELSE，则将引发 CASE_NOT_FOUND 异常。

下面是一个示例。

CASE
WHEN x BETWEEN 0 AND 10 THEN
  msg := 'value is between zero and ten';
WHEN x BETWEEN 11 AND 20 THEN
  msg := 'value is between eleven and twenty';
END CASE;                                

简单循环

[<<label>>]
LOOP
  statements
END LOOP [ label ];

简单循环定义无条件的循环，这种循环将无限重复，直至由 EXIT 或 RETURN 语句终止。在嵌套循环中，EXIT 和 CONTINUE 可以使用可选的标签来指定 EXIT 和 CONTINUE 语句引用哪个循环。

下面是一个示例。

CREATE OR REPLACE PROCEDURE simple_loop()
LANGUAGE plpgsql
AS $$
BEGIN
  <<simple_while>>
  LOOP
    RAISE INFO 'I am raised once';  
    EXIT simple_while;
    RAISE INFO 'I am not raised';
  END LOOP;
  RAISE INFO 'I am raised once as well';
END;
$$;                

退出循环

EXIT [ label ] [ WHEN expression ];

如果没有 label，则终止最内部的循环，接下来运行 END LOOP 后面的语句。如果有 label，则必须是当前或某个更靠外级别的嵌套循环或块的标签。然后，指定的循环或块终止，继续由循环或块对应的 END 之后的语句控制。

如果指定了 WHEN，则循环仅在 expression 为 true 时退出。否则，控制将传递到 EXIT 之后的语句。

您可以对所有类型的循环使用 EXIT，它不限于仅由无条件循环使用。

用于 BEGIN 块时，EXIT 将控制传递到块结束之后的语句。为此必须使用标签。在匹配 BEGIN 块时，永远不考虑无标签的 EXIT。

下面是一个示例。

CREATE OR REPLACE PROCEDURE simple_loop_when(x int)
LANGUAGE plpgsql
AS $$
DECLARE i INTEGER := 0;
BEGIN
  <<simple_loop_when>>
  LOOP
    RAISE INFO 'i %', i;
    i := i + 1;
    EXIT simple_loop_when WHEN (i >= x);
  END LOOP;
END;
$$;                     

继续循环

CONTINUE [ label ] [ WHEN expression ];

如果未给出 label，则执行跳转到最内部循环的下一次迭代。即，跳过循环正文中剩余的所有语句。然后，控制返回到循环控制表达式（如果有），确定是否需要下一次循环迭代。如果存在 label，它指定将继续其执行的循环的标签。

如果指定了 WHEN，则循环的下一次迭代仅在 expression 为 true 时开始。否则，控制将传递到 CONTINUE 之后的语句。

您可以对所有类型的循环使用 CONTINUE，它不限于仅由无条件循环使用。

CONTINUE mylabel;

WHILE 循环

[<<label>>]
WHILE expression LOOP
  statements
END LOOP [ label ];

只要 boolean-expression 求值为 true，WHILE 语句就会重复一组语句。在每个条目即将进入循环正文之前对表达式进行检查。

下面是一个示例。

WHILE amount_owed > 0 AND gift_certificate_balance > 0 LOOP
  -- some computations here
END LOOP;

WHILE NOT done LOOP
  -- some computations here
END LOOP;                  

FOR 循环（整数变体）

[<<label>>]
FOR name IN [ REVERSE ] expression .. expression LOOP
  statements
END LOOP [ label ];

FOR 循环（整数变体）创建一个循环，对一系列整数值进行迭代。变量名称自动定义为整数类型，并且仅在循环中存在。忽略循环中任何现有的变量名称定义。给出了范围下限和上限的两个表达式，在进入循环时求值一次。如果您指定 REVERSE，则在每次迭代之后减去步进值而不是累加。

如果下限大于上限（在 REVERSE 情况下则为小于），循环正文不运行。不引发错误。

如果将标签附加到 FOR 循环，则您可以使用限定名称，通过该标签应用整数循环变量。

下面是一个示例。

FOR i IN 1..10 LOOP
  -- i will take on the values 1,2,3,4,5,6,7,8,9,10 within the loop
END LOOP;

FOR i IN REVERSE 10..1 LOOP
  -- i will take on the values 10,9,8,7,6,5,4,3,2,1 within the loop
END LOOP;                

FOR 循环（结果集变体）

[<<label>>]
FOR target IN query LOOP
  statements
END LOOP [ label ];

target 是一个记录变量，或者是标量变量的逗号分隔列表。目标依次分配给查询生成的每一行，并为每一行运行循环正文。

FOR 循环（结果集变体）使得存储过程可以迭代查询的结果并相应操作数据。

下面是一个示例。

CREATE PROCEDURE cs_refresh_reports() AS $$
DECLARE
  reports RECORD;
BEGIN
  FOR reports IN SELECT * FROM cs_reports ORDER BY sort_key LOOP
    -- Now "reports" has one record from cs_reports
    EXECUTE 'TRUNCATE TABLE ' || quote_ident(reports.report_name);
    EXECUTE 'INSERT INTO ' || quote_ident(reports.report_name) || ' ' || reports.report_query;
  END LOOP;
  RETURN;
END;
$$ LANGUAGE plpgsql;                   

具有动态 SQL 的 FOR 循环

[<<label>>]
FOR record_or_row IN EXECUTE text_expression LOOP 
  statements
END LOOP;

具有动态 SQL 的 FOR 循环使得存储过程可以迭代动态查询的结果并相应操作数据。

下面是一个示例。

CREATE OR REPLACE PROCEDURE for_loop_dynamic_sql(x int)
LANGUAGE plpgsql
AS $$
DECLARE
  rec RECORD;
  query text;
BEGIN
  query := 'SELECT * FROM tbl_dynamic_sql LIMIT ' || x;
  FOR rec IN EXECUTE query
  LOOP
    RAISE INFO 'a %', rec.a;
  END LOOP;
END;
$$;

打开供选择：游标变量已打开，并提供了指定的查询来运行。该游标不能已经打开。此外，它必须已经声明作为未绑定游标（即，作为简单 refcursor 变量）。SELECT 查询的处理方式与 PL/pgSQL 中的 SELECT 语句相同。

OPEN cursor_name FOR SELECT ...;                     

下面是一个示例。

OPEN curs1 FOR SELECT * FROM foo WHERE key = mykey;    

打开供执行：游标变量已打开，并提供了指定的查询来运行。该游标不能已经打开。此外，它必须已经声明作为未绑定游标（即，作为简单 refcursor 变量）。以字符串表达式格式指定查询的方式，与在 EXECUTE 命令中的方式相同。此方法提供了灵活性，使得查询可以在不同运行之间变化。

OPEN cursor_name FOR EXECUTE query_string;

下面是一个示例。

OPEN curs1 FOR EXECUTE 'SELECT * FROM ' || quote_ident($1);

打开绑定游标：这种类型的 OPEN 用于打开的游标变量，在声明时已经将查询绑定到其上。该游标不能已经打开。只有在声明了游标来获取参数时，才必须显示实际参数值表达式的列表。这些值在查询中提交。

OPEN bound_cursor_name [ ( argument_values ) ];

下面是一个示例。

OPEN curs2;
OPEN curs3(42);

FETCH 从游标将下一行检索到目标中。目标可以是行变量、记录变量，或者是简单变量的逗号分隔列表，就像与 SELECT INTO 一样。对于 SELECT INTO，您可以检查特殊变量 FOUND 以查看是否获取了某行。

FETCH cursor INTO target;

下面是一个示例。

FETCH curs1 INTO rowvar;

CLOSE 将关闭打开游标下的门户。您可以使用此语句，在事务结束之前释放资源。您也可以使用此语句再次释放游标成为打开状态。

CLOSE cursor;

下面是一个示例。

CLOSE curs1;